recover-dir

Disculpas y gracias.

Mon, 25 Jun 2007 05:09:27 -0500

Este fin de semana el servidor ha estado caido, ya sois mas de 2000 los que habeis descargado la aplicacion recover-cct.
Y logicamente el servidor no estaba preparado.
Pero otra vez esta en linea un saludo y gracias a todos.

Recover cct (unprotect cct Macromedia Director Shockwave cast)

Wed, 23 May 2007 08:43:58 -0500

Ultimamente ha llegado a mi correo bastantes peticiones referentes a desproteger archivos *.cct (Macromedia Director Shockwave cast).
As� que desde aqui doy gracias a Dz63@hotmail.de por animarme a realizarlo.
As� que aqui teneis la aplicacion para hacerlo.
Es muy sencillo, ejecutais el exe, y os preguntara 2 veces por el archivo, simplemente seleccionarlo.
Download

Modificar el estilo de los Hypelinks

Tue, 22 Nov 2005 12:50:18 -0600

Una de las mejoras que yo esperaba con director MX 2004 es poder acceder a las propiedades de los Hypelinks en los textos. Pero esto no ha llegado a si que seguimos igual. Con el aspecto tipico de un link (pero de hace 5 a�os) azul y subrayado.

En los ultimo dias he tenido varias preguntas acerca de este temas, asi que me he decidido crear un comportamiento para poder cambiar el aspecto "aburrido" de los hyperlinks. Con el podras cambiar el color de los hyperenlaces tanto el inical como el de estado de rollover.

La unica parte que tendras que modificar a gusto es esta parte

on hyperlinkClicked me,data
go to frame data.integer
end hyperlinkClicked

Ya que os dirigira a un frame, podeis cambiarlo por un gotonetpage , o lo que necesiteis.

Aqui el codigo:

property texto
property posicion_raton
property link,
property num_link,
property empieza,
property termina
property pColor
property pLink, pBold_ini
property pBold_roll
property pUnderline_ini
property pUnderline_roll
property formato_roll
property formato_ini

on beginSprite me
  formato_roll=[]
  if pBold_roll then formato_roll[formato_roll.count+1]=#bold
  if pUnderline_roll then formato_roll[formato_roll.count+1]=#underline
  formato_ini=[]
  if pBold_ini then formato_ini[formato_ini.count+1]=#bold
  if pUnderline_ini then formato_ini[formato_ini.count+1]=#underline
  texto = the member of sprite the currentspritenum
  texto.useHypertextStyles = FALSE
  empieza=1
  termina=texto.text.char.count
  link = texto.hyperlinks
  colorea
end

on mouseWithin me
  global posicion_raton
  posicion_raton = pointToChar(sprite the currentspritenum,the mouseLoc)
  if enlaces(me,posicion_raton).count then
    empieza = enlaces(me,posicion_raton)[1]
    termina = enlaces(me,posicion_raton)[2]
    texto.char[empieza..termina].color = pLink
    if formato_roll.count then
      TEXTO.char[EMPIEZA..TERMINA].fontStyle = formato_roll
      cursor 280
    else
      TEXTO.char[EMPIEZA..TERMINA].fontStyle = [#plain]
      cursor 280
    end if
  else
    colorea
  end if

end

on mouseleave me
colorea
end

on enlaces me,palabra
  repeat with x in link
    primera_letra = x.getAt(1)
    if primera_letra > palabra then
      exit repeat
    else if palabra >= primera_letra then
      if x.getAt(2) >= palabra then
        return x
      end if
    end if

  end repeat

return []
end

on hyperlinkClicked me,data
go to frame data.integer
end hyperlinkClicked

on colorea me
  num_link = count(link)
  Repeat with b = 1 to NUM_LINK
    a = link[b]
    EMPIEZA = a[1]
    TERMINA = a[2]
    TEXTO.char[EMPIEZA..TERMINA].color= pColor
    if formato_ini.count then
      TEXTO.char[EMPIEZA..TERMINA].fontStyle = formato_ini
          else
      TEXTO.char[EMPIEZA..TERMINA].fontStyle = [#plain]

    end if
  end repeat
  cursor -1
end

on getPropertyDescriptionList me

  p = [:]
  p.addProp(#pColor, [#format : #string, #comment : "�Color Inicial?",#default : color(#rgb, 0, 0, 255)])
  p.addProp(#pUnderline_ini, [#format : #boolean, #comment : "Subrayado al inicio?", #default : 1, #range : [1, 0]])
  p.addProp(#pBold_ini, [#format : #boolean, #comment : "Bold al inicio?", #default : 0, #range : [1, 0]])
  p.addProp(#pLink, [#format : #string, #comment : "�Color al rollover?",#default : color(#rgb, 255, 0, 0)])
    p.addProp(#pUnderline_roll, [#format : #boolean, #comment : "Subrayado al rollover?", #default : 1, #range : [1, 0]])
   p.addProp(#pBold_roll, [#format : #boolean, #comment : "Bold al rollover?", #default : 0, #range : [1, 0]])
  return p
  put p
end

Introducir SOLAMENTE valores num�ricos en un campo de texto

Thu, 30 Jun 2005 14:01:48 -0500

Bueno, hoy voy a poner otro de mis Behaviours de uso cotidiano. La verdad que no tengo nada en contra de los que vienen con Director, pero siempre he preferido crearme los mios.

Hoy vamos a ver un Behaviour que nos va a permitir qu een un campo de texto solamente se puedan introducir n�meros.

on KeyDown me
  set permitidos to [18,19,20,21,22,23,25,26,28,29,51,82,83,84,85,86,87,88,89,91,92]
  if getPos(permitidos, the KeyCode) = 0 then
    dontpassevent
  else if the keyCode = 51 then
    texto_introducido= (sprite(me.spritenum).member.text)
    len=length(sprite(me.spritenum).member.text)
    if len <= 1 then
      sprite(me.spritenum).member.text=""
    else
      sprite(me.spritenum).member.text= texto_introducido.char[1..(texto_introducido.char.count -1)]
    end if
  else
    if the keypressed.value >= 0 then
      sprite(me.spritenum).member.text =sprite(me.spritenum).member.text &the keyPressed
      longitud=length(sprite(me.spritenum).member.text)
      set the selStart to longitud
      set the selEnd to longitud
    end if
  end if
end

Como podeis ver es muy generico, se podria mejor asi que si alguno se anima... aqui os espero.

Behaviours para Botones (mantener un boton activado)

Wed, 29 Jun 2005 16:48:07 -0500

Hoy me apetece incluir uno de lo Behaviours de mi galeria de uso propio. En esta ocasion este behaviour permite que al pulsar un boton se quede seleccionado o activado, y a su vez deseleccione otro boton en el caso que estubiera activado.

Otra opcion interesante es que cuando esta "seleccionado" no pasa ningun evento a otro handler. Es decir que si adem�s de tener este behaviour asignado a un boton, tenemos otro que se ejecuta al pulsar, nuestro behaviour no permitira que se ejecute.Entes de empezar tenemos que tener una serie de consideraciones. Como llamamos a los botones: l aimagen que usemos como bot�n de rollover tendra que usar el apendice "_roll", la imagen del clik "_clik" y la imagen para el boton seleccionado "_sol".
Si nuestra imagen del cast para el primer boton se llama "Opcion1", el resto habria que nombrarlos:"opcion1_roll", "opcion1_clik" y "opcion1_sel".

Otra consideracion:
Usando : sendallsprites(#activate, sprite(me.spritenum)), con una sencilla comprobacion conseguimos que cuando activamos un boton se desactiven el resto.

property mySprite
property myMember
property myRollMember
property myClickMember
property mySelectedMember
property pRollMember
property pClickMember
property pSelectedMember
property pSelected

on getPropertyDescriptionList me
  p = [:]
  p.addProp(#pRollMember, [#format : #boolean, #comment : "�Tiene elemento para el rollover?", #default : 1, #range : [1, 0]])
  p.addProp(#pClickMember, [#format : #boolean, #comment : "�Tiene elemento para el click?", #default : 0, #range : [1, 0]])
  p.addProp(#pSelectedMember, [#format : #boolean, #comment : "�Tiene elemento para el seleccionado?", #default : 0, #range : [1, 0]])
  return p
end
on beginSprite me
  pSelected=false
  mySprite=sprite(me.spriteNum)
  myMember=mySprite.member
  if pRollMember then
    myRollMember=member(myMember.name&"_roll")
  end if
  if pClickMember then
    myClickMember=member(myMember.name&"_click")
  end if
  if pSelectedMember then
    mySelectedMember=member(myMember.name&"_sel")
  end if
end
on endSprite me
  mySprite.member=myMember
end
on mouseEnter me
  if not pSelected then
    mySprite.cursor=280
    if pRollMember then
      mySprite.member=myRollMember
    end if
  else
    mySprite.cursor=-1
  end if
end
on mouseLeave me
  if not pSelected then
    mySprite.cursor=0
    miembro=myMember
    mySprite.member=miembro
  end if
end
on mouseDown me
  if not pSelected then
    if pClickMember then
      mySprite.member=myClickMember
    end if
  end if
end
on mouseUp me
  if pSelectedMember then
    if pSelected then
      stopevent()
    else
      pSelected=not pSelected
      mySprite.member=mySelectedMember
      sendallsprites(#activate, sprite(me.spritenum))
    end if
  else
    if pRollMember then
      mySprite.member=myRollMember
    else
      mySprite.member=myMember
    end if
  end if
end

on mouseUpOutside me
mySprite.member=myMember
end

on activate me, quien
  if quien <>sprite(me.spritenum) then
    mySprite.member=myMember
    pSelected=false
  end if
end

Abrir aplicaciones externas manteniendo el foco.

Wed, 29 Jun 2005 15:44:15 -0500

El otro dia una amiga tenia que terminar un desarrollo de una aplicaci�n que corria en "background", la cual a ciertas horas lanzaba distintos eventos (clips ens dvd, animaciones en flash...).
El problema surg�a cuando estaba corriendo un dvd y queria lanzar un flash. El flash no era capaz de mantener el "foco". La opcion podria ser usar Zinc
Pero aqui estamos para aprender Director, as� que vamos a usar esta herramienta para crear una aplicaci�n que nos permita conseguirlo.Para empezar a hemos de crear una aplicacion a la que hemos de pasar parametros. El funcionamiento era el siguiente, un archivo *.bat tenia que llamar a nuestra apliacion indic�ndole el archivo que queremos abrir. En este caso eran unos Flash pero compilados como exe. Estos flash cuando terminaban de ejecutarse se cerraban, y con ellos nuestra aplicaci�n que se quedaba otra vez esperando otra llamada.

Quiz� alguno de vosotros no conocia la capacidad que tiene Director para ejecutarse con parametros, para ello nada mas sencillo que el comando "the commandline".

En menos de 20 lineas de codigo lo tenemos hecho.

Creamos un Handler Preparemovie:

global wnd
on preparemovie me
  set the visible of the stage= false
    open the moviepath&the commandline
  wnd = baActiveWindow()
  baSetWindowState(wnd, "StayOnTop" )
end

Como veis primero hacemos invisible el stage, (en mi caso adem�s la movie tenia un tama�o de 1 pixel, y se compil� "In a Windows" y sin la barra de titulo.
El siguiente paso es abrir la aplicaci�n, usamos ahora "The commandline". En este caso los ejecutables estaban en la misma carpeta que la aplicaci�n de Director, por eso usamos "The moviepath".
Adem�s us� Buddy Api. Con este xtra capturamos el evento de la aplicaci�n que abrimos, pasandolo a la variable "wnd".

El paso siguiente consiste en mantener la aplicacion que hemos abierto con el foco mientras este ajecutandose, y en el caso contrario, cerrar la aplicaci�n de Director.
Creamos un FrameScript en el Score:

global wnd
on exitFrame me
  if baWindowExists(wnd ) = 1 then
    baSetWindowState(wnd, "StayOnTop" )
  else
   halt
  end if
end
on enterframe me
  play the frame
end

Como podeis ver hacemos una comprobaci�n, si el evento existe: baSetWindowState(wnd, "StayOnTop") , en el caso contrario (la aplicaci�n se ha cerrado), cerramos nuestro programa.

Compilamos llamandolo "Abridor.exe"y a probar, creamos una archivo Bat, con solo esta linea:
projector.exe miarchivo.exe
Doble clik sobre el bat y... ��FUNCIONA!!.

Aqui teneis el proyecto compilado para que hagais pruebas. Por cuestion de espacio el flash no est� incluido, pero podeis probar con lo que querais (recordar modificar el archivo *.bat)

Capturar una imagen de un fotograma de Flash 1� Parte

Wed, 25 May 2005 19:10:11 -0500

El otro dia me preguntaron como poder capturar y generar una imagen de un frame determinado de Flash, y dado la utilidad que puede tener, por ejemplo para crear transiciones entre animaciones de flash y el stage de Director, me he decidido a hacer un "behaviour" para automatizarlo. Simplemente se arrastra sobre un elemento y se introducen los parametros.

Teniendo este codigo no creo que tengais problemas para crear una funcion y llamarla, en el caso que no querais trabajar como behaviour.

property pImagen_alpha, pImagen_mostrar, pFlash_member, pFlash_frame

on getPropertyDescriptionList me
  if the currentSpriteNum = 0 then exit
  theMember = sprite(the currentSpriteNum).member
  theMemberNumber = theMember.number
  p = [:]
  p.addProp(#pImagen_alpha, [#format : #graphic, #comment : "Que elemento usas como contenedor del Alpha?", #default: member (theMemberNumber )] )
  p.addProp(#pImagen_mostrar, [#format : #graphic, #comment : "Que elemento usas para mostrar la imagen?", #default: member (theMemberNumber)])
  p.addProp(#pFlash_member, [#format : #flash, #comment : "Que flash member vas a usar?", #default: member (theMemberNumber)])
  p.addProp(# pFlash_frame, [ #format : #integer, #comment : "Que frame del flash quieres capturar", #default:#0])
  return p
end

on mouseup me
  Tamano= pFlash_member.rect
  pFlash_member.posterFrame =pFlash_frame
  pImagen_mostrar.image = pFlash_member.image
  pImagen_alpha.image = image(pImagen_mostrar.width, pImagen_mostrar.height,32)
  ( image (pImagen_mostrar.width, pImagen_mostrar.height, 32)).copyPixels( pImagen_mostrar.image, Tamano, pImagen_mostrar.rect,[#maskImage:pImagen_alpha.image.createMatte()])
end

Espero tener tiempo y hacer dos entregas mas. Una para exportar todos los fotogrmas ( o un rango de ellos), y otra para exportarlos como imagenes externas en formato jpg.

Espero que os sea d eutilidad

Links de Macromedia Director

Thu, 12 May 2005 17:33:26 -0500

Aqui os dejo un listado de Links interesantes relacionados con Macromedia Director
http://www.lingolandia.com
http://groups.google.es/groups?group=es&hl=es&lr=&group=macromedia.general.espana
http://www.furrypants.com/loope/index.htm http://www.fbe.unsw.edu.au/learning/director/ http://www.dreamlight.com/insights/07/ http://www.andyw.com/director/ -- tips andn tricks
http://www.director-onine.com -- At�culos y foro
http://www.mediamacros.com/ -- Muchos ejemplos
http://www.xtrasy.com/ -- quiz� uno de los mejores sitios para buscar Xtras
http://www.updateStage.com/ -- quirk list, articulos y xtras
http://www.lingoworkshop.com/ -- Lingo avanzado
http://www.zeusprod.com/ -- lingo y mas lingo
http://www.proscenia.net/resources/tutorials/director/d1/index.html --Tutorial
http://www.shocknet.org.uk/ -- internet, XML, ASP/SQL, database connectivity
http://www.jmckell.com/ -- Animation Math in Lingo
http://www.vtc.com/products/directormx2004.htm -- Cursos en formato Quicktime
http://www.shockwave3d.com/ -- shockwave games
http://www.chromelib.com/ -- shockwave 3D behavior library
http://poppy.macromedia.com/~thiggins/ -- Thomas Higgins
http://multimediahelp.org/home/director.html?action=downloads-- Pues eso descargas
http://nonlinear.openspark.com/alpha/ -- James Newton�s site. Ejemplos
http://www.macromedia.com/support/director/
http://www.robotduck.com/learning/introduction/introduction1.htm -- tutoriales
http://www.mcli.dist.maricopa.edu/director/ --Director Web
www.directordevelopers.com/lingopark/

Tutorial de Director en Espa�ol

Tue, 10 May 2005 18:56:09 -0500

Desde la web www.coursemedia.net podemos acceder a un MUY BUEN curso de Director:

"Este tutorial sobre Macromedia Director es otro de los elaborados en su momento para Flash-es.net, y aunque hay algunas versiones del mismo por la web �sta que ofrece Coursemedia.net es la original."

Una gran iniciativa que hay que apoyar, adem�s de ser GRATIS esta bajo licencia Creative Commons.

Chequear que no nos ha quedado ningun castmember linkado

Tue, 10 May 2005 18:51:30 -0500

A muchos desarrallodares nos a ocurrido alguna vez que hemos cerrado una aplicacion y al grabarla en el cd-rom, nos pide una imagen que no esta.
Muchas veces esto sucede por que cuando hemos importado los elementos graficos en lugar de usar una importacion standar hemos usado link to External File.
La soluci�n, abrir las fuentes y buscar, aqui os dejo un script para automatizar este proceso.

on analiza me
  repeat with a = 1 to the number of castLibs
    repeat with b=1 to the number of members of castlib a
      if (member b of castlib a).type = #bitmap and (member b of castlib a).filename <>"" then
        put "El elemento"&"e&(member b of castlib a).name"e&&"Esta linkado a"&"e& (member b of castlib a).filename "e
        importFileInto member(member b of castlib a), (member b of castlib a).fileName
      end if
    end repeat
  end repeat
end

Como podreis ver nos dara una salida en la ventana de message avisandonos que elemento es el linkado, y en la siguiente l�nea con importFileInto tranformamos el liked member por un miembro interno.